2.1. Hoeveel personen kunnen er per vestiging wonen?

Concepten

• Capaciteitswaarde
• Kwaliteit
• Mens
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Wooneenheid

Relaties

• deel van
• deel van
• geïdentificeerd door
• heeft capaciteitsobject
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde

Eigenschappen

• heeft datawaarde

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: RIVM 2.1
2# Parameters: 
3# Ontologie: versie 2.2.0 of nieuwer
4 
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8
9SELECT 
10  (?vestiging AS ?Indeling)
11  (SUM(?unitCapacity) AS ?Capaciteit_aantal_bewoners)
12WHERE {
13  {
14    SELECT ?vestiging ?wooneenheid (MAX(?waarde) AS ?unitCapacity)
15    WHERE {
16      ?wooneenheid 
17          a onz-org:WoonEenheid ;
18          onz-g:hasQuality ?cap .
19
20      ?cap
21          a onz-g:Quality ;
22          onz-g:hasQualityValue ?cap_waarde .
23
24      ?cap_waarde a onz-g:CapacityValue ;
25          onz-g:hasDataValue ?waarde ;
26          onz-g:hasCapacityObject onz-g:Human .
27
28      {
29        # Per vestiging
30        ?wooneenheid onz-g:partOf ?locatie .
31        ?locatie 
32            a onz-g:StationaryArtifact ;
33            onz-g:partOf* ?vestiging_uri .
34                
35        ?vestiging_uri a onz-org:Vestiging ;
36            onz-g:identifiedBy ?vest_nr .
37
38        ?vest_nr a onz-org:Vestigingsnummer ;
39            onz-g:hasDataValue ?vestiging .
40      }
41      UNION
42      {
43        # Totaal organisatie (de capaciteiten van de vestigingen én die zonder vestigingsnummer)
44        BIND("Organisatie" AS ?vestiging)
45      }
46    }
47    GROUP BY ?vestiging ?wooneenheid
48  }
49}
50GROUP BY ?vestiging
51ORDER BY ?vestiging
52